Utilisateur:Malosse/Gnuplot

Génération de l'œil de chat de Queney dans l'article (Rotor (météorologie)) à utiliser sous Gnuplot :

set samples 1000000
set yrange [0:3000]
a = 20
k = 0.001
gamma = 0.02
set xlabel "Distance (mètres)"
set ylabel "Altitude (mètres)"
set terminal jpeg size 2560, 1920 font "Times-New-Roman, 30"
set output "Œil de chat (rotor).jpg"
set arrow from 2000,900 to 2700,1400 lc rgb "blue" lw 0.5
set arrow from 8300,900 to 9000,1400 lc rgb "blue" lw 0.5
set arrow from 14600,900 to 15300,1400 lc rgb "blue" lw 0.5
set arrow from 5500,100 to 4000,100 lw 2 lc rgb "orange"
set arrow from 11800,100 to 10300,100 lw 2 lc rgb "orange"
set arrow from 18100,100 to 16600,100 lw 2 lc rgb "orange"
plot [0:20000] for [n=0:4] \
(-a *  sin(k*x) + sqrt(a*a * sin(k* x)**2 - (n+0.5)*a*a/5))/gamma lw 2 lc rgb "orange" notitle,\
(-a *  sin(k*x) + sqrt(a*a * sin(k* x)**2 - (4.9)*a*a/5))/gamma lw 2 lc rgb "orange" notitle,\
for [n=0:4] \
(-a *  sin(k*x) - sqrt(a*a * sin(k*x)**2 - (n+0.5)*a*a/5))/gamma lw 2 lc rgb "orange" notitle, \
(-a *  sin(k*x) - sqrt(a*a * sin(k*x)**2 - (4.9)*a*a/5))/gamma lw 2 lc rgb "orange" notitle, \
for [n=0:9] \
(-a *  sin(k*x) + sqrt(a*a * sin(k*x)**2 + (n+0.5)*a*a/5))/gamma lt rgb "blue" notitle, \
-2 * a *  sin(k*x)/gamma lw 3.0 lc rgb "red" notitle